PadRight, PadLeft

Padding changes the length of VB.NET Strings. It adds extra characters to the right or left of the String data.

PadLeft adds spaces to the left side—and PadRight adds to the right. Both also support other padding characters.

PadLeft example

This program creates an array filled with 3 Strings. It then loops over these Strings. Each String has up to five characters of padding added to the left.

Module Module1
    Sub Main()
        Dim words() As String = {"A", "Net", "Perls"}
        ' Loop over words.
        For Each w As String In words
            Console.WriteLine(w.PadLeft(5))
        Next
    End Sub
End Module
    A
  Net
Perls

PadRight example

The PadLeft Function is paired with PadRight. Here we add complexity by using a Dictionary collection. For keys we use Strings. For values we use Integers.

Module Module1
    Sub Main()
        ' Create Dictionary.
        Dim dict As Dictionary(Of String, Integer) = New Dictionary(Of String, Integer)
        dict.Add("Cat", 5)
        dict.Add("Mouse", 1)
        dict.Add("Leopard", 9)
        dict.Add("Asp", 10)

        ' Loop over pairs.
        For Each pair As KeyValuePair(Of String, Integer) In dict
            ' Pad right of key.
            Console.Write(pair.Key.PadRight(10))
            ' Pad left of value.
            Console.WriteLine(pair.Value.ToString().PadLeft(2))
        Next
    End Sub
End Module
Cat        5
Mouse      1
Leopard    9
Asp       10

Example 3

PadLeft and PadRight can add any Char value you like. In this program we use a period as the second argument to PadRight. And for PadLeft we pass a hash sign.

Module Module1
    Sub Main()
        ' Pad with . and #
        Console.Write("Sam".PadRight(10, "."c))
        Console.WriteLine("28173".PadLeft(6, "#"c))
        ' Next line.
        Console.Write("Mark".PadRight(10, "."c))
        Console.WriteLine("137".PadLeft(6, "#"c))
    End Sub
End Module
Sam.......#28173
Mark......137

Text-based display of data is common. It is an easy way to format tables in console programs. PadLeft and PadRight help in code that displays numeric data.